IchigoJamの音痴を治す

研究の動機  
夏休みにワークショップで、こどもパソコンIchigoJamを作りました。PLAY命令で音楽を演奏して楽しかったです。

10PLAY“O5CDEFEDCREFGAGFERCRCRCRCRCDEFEDCR”

でも、なんだか音痴です。IchigoJamを上手に歌わせる研究をしました。

IchigoJamとは  
手のひらにのせられる大きさの、プログラミング専用こどもパソコンです。

IchigoJamにテレビとキーボードをつなげば、すぐにプログラミングを始められます。

PLAYコマンドで音階を鳴らす

10 CLS:?"PLAY TEST"

20 ?"O1":PLAY "T60O1C1RD1RE1RF1RG1RA1RB1R"

30 IF SOUND()CONT

40 ?"O2":PLAY "T60O2C1RD1RE1RF1RG1RA1RB1R"

50 IF SOUND()CONT

60 ?"O3":PLAY "T60O3C1RD1RE1RF1RG1RA1RB1R"

70 IF SOUND()CONT

80 ?"O4":PLAY "T60O4C1RD1RE1RF1RG1RA1RB1R"

90 IF SOUND()CONT

100 ?"O5":PLAY "T60O5C1RD1RE1RF1RG1RA1RB1R"

110 IF SOUND()CONT

チューナーで音の高さを測りました。

平均律の周波数

ラ=440Hz 半音で×2の１２乗根 2^(1/12)≒1.059倍

正しい周波数からはずれているので、IchigoJamの音は音痴に聞こえます。

画面の1/60秒を使って音程を決めているのでずれます。  
BASICに組み込まれているので治すことができません。

PWM 数１,数２,数３

外部出力OUT2-5に

数2で指定するパルスを出力する  
数3で周期を指定

単位は0.01ミリ秒

４４０Hzの音を出すプログラム

10 PWM 5,113,227:WAIT 60:OUT5,0

440Hz 1秒に440回パルスを出す。  
１回のパルスは1÷440≒0.00227 秒単位 227 0.01ミリ秒単位

ONにしたら227ミリ秒の50%の時間待ってOFFにする。

0.01ミリ秒の単位で音の高さを正確に合わせることができます。

ドレミを計算

オルゴール

画面がスクロールして　O　が左端に来ると　対応する音が鳴る。  
F1で画面をクリア　F5でRUN  
Insertで上書きモードにして　O　を入力する。  
１行目にカーソルをもっていき、EnterでRUN

プログラム

10 'MUSIC BOX

20 M=12

30 S="ﾗ--ｼ--ﾄﾞ-ﾚ--ﾐ--ﾌｧ-ｿ--ﾗ--ｼ--ﾄﾞ-ﾚ--ﾐ--"

40 LET[0],227,202,191,170,152,143,128,114,101,96,85,76

50 OUT5,0:L=10:N=2:P=50

60 FORJ=0TO31

70 IFSCR(0,1)=0GOTO@L

80 IFSCR(0,1)=32GOTO@L

90 F=-1

100 FORI=1TOM

110 IFSCR(0,I)=79:F=M-I

120 NEXT

130 IFF>=0PWM5,[F]\*P/100,[F]

140 WAITL-N

150 OUT5,0:WAITN:SCROLL3

160 NEXT

170 @L:CLS:FORI=1TOM:LC0,I

180 FORJ=0TO2

190 ?CHR$(PEEK(S+(M-I)\*3+J));

200 NEXT

210 FORJ=3TO31:?"-";:NEXT

220 NEXT

230 @E:LC0,0:?"RUN"

240 LC0,M+2:END

いろいろな音階

半音階  
黒鍵の音・♯♭もすべて鳴らせる

20 M=20

30 S="ﾗ--ｼbｰｼ--ﾄﾞ-ﾄﾞ#ﾚ--ﾐb-ﾐ--ﾌｧ-ﾌｧ#ｿ--ｿ#-ﾗ--ｼbｰｼ--ﾄﾞ-ﾄﾞ#ﾚ--ﾐb-ﾐ--"

40 LET[0],227,215,202,191,180,170,161,152,143,135,128,120,114,107,101,96,90,85,80,76

旋律的短音階

長調の曲を暗くします。

20 M=11

30 S="ｼ--ﾄﾞ-ﾚ--ﾐb-ﾌｧ-ｿ--ｿ#-ｼ--ﾄﾞ-ﾚ--ﾐb-"

40 LET[0],202,191,170,161,143,128,120,101,96,85,80

琉球音階

ドミファソシドの音階　沖縄民謡になる

20 M=8

30 S="ｼ--ﾄﾞ-ﾐ--ﾌｧ-ｿ--ｼ--ﾄﾞ-ﾐ--"

40 LET[0],202,191,152,143,128,101,96,76

ヨナ抜き音階

ドレミソラド　四ファと七シを抜く。演歌になる。

20 M=8

30 S="ｼ--ﾄﾞ-ﾐ--ﾌｧ-ｿ--ｼ--ﾄﾞ-ﾐ--"

40 LET[0],202,191,152,143,128,101,96,76

ゲゲゲ音階

ミソを♭にする　ゲゲゲのゲ～

20 M=11

30 S="ﾗ--ｼ--ﾄﾞ-ﾚ--ﾐb-ﾌｧ-ﾌｧ#ﾗ--ｼ--ﾄﾞ-ﾚ--ﾐb-"

40 LET[0],227,202,191,170,161,143,135,114,101,96,85,80

画面を保存する

画面に表示したOはスクロールして消えてしまうので、保存するプログラムを作りました。  
IchigoJamはプログラムの長さに関係なく、1Kbyteのメモリをまとめて保存します。プログラムが入っていない後半#D00～に、画面のデータ#900～の768byteをCOPYして、プログラムと一緒に保存します。

230 @E:LC0,0:?"LRUN";FILE()

保存してあるプログラムを毎回呼び出すように変更

10 'SCR-SAVE

20 IFSCR(0,1)<>0GOTO@S

30 @L:COPY #900,#D00,768

40 LC0,22:END

50 @S:COPY #D00,#900,768

60 SAVE FILE():END

画面の保存・読み込みプログラム  
(0,1)に文字があると画面をコピーして自分自身をSAVEする。  
画面をクリアしてLRUNで実行すると保存してある画面を読み込む。